Ingegneria Forum

Adesso inseriamo dei "valori di lavoro" ai carichi (per brevità per adesso consideriamone presenti solo 2).

Ci proponiamo adesso di costruirci la tabella coi carichi risultanti sul piano intradossso del plinto (piano passante per la testa dei pali).

Ciascun carico, applicato nel punto x,y e sul piano di estradosso del plinto, dovà essere riportato sul baricentro della palificata e sul piano testa-pali.

Predisponiamo quindi una settima tabella del tutto uguale nella struttura a quelle dei carichi applicati e del peso del plinto moltiplicato per gamma.F

Questa tabella potremmo riempirla mediante una serie di formule di foglio, oppure ricorrendo al codice. Ho parlato troppo spesso di codice in questo 3d, ma preso dalla foga di pervenire a qualcosa di immediatamente utilizzabile, non vi ho mai fatto ricorso. Penso sia arrivato il tempo di farlo.

Prima di passare al codice (che spero di poter iniziare a trattare domani) scriviamo le formule necessarie a ricavare le risultanti,

diamo l'indice "o" alle azioni dovute al peso proprio (che vi ricordo sono gia ricondotte nel baricentro della palificata) e l'indice "i" al generico carico.

Le azioini risuoltanti su piano testa pali e nel baricentro della palificata li determiniamo attraverso le seguenti formule:

Fx = Fxo + somma.i[Fxi]
Fy = Fyo + somma.i[Fyi]
Fz = Fzo + somma.i[Fzi]

Mx = Mxo +somma.i[ Mxi +Fzi*(yi-yg) - Fyi*Hp]
My = Myo +somma.i[ Myi - Fzi*(xi-xg) + Fxi*Hp]

Mz = Mzo +somma.i[ Mzi - Fxi*(yi-yg) + Fyi*(xi-xg)]

Alla prossima.

Nel nostro codice dovremo fare eseguire almeno due cicli, quello più esterno per le combo e quello piu interno per i carichi.
Ci serve quindi sapere il numero delle combinazioni da esaminare ed il numero di carichi presenti.
Dimensioniamo allora altre due variabili che chiamo N_combo e N_carichi e questi sono degli interi

Dim N_combo as integer, N_carichi as integer

e ne richiamiamo subito i valori dalle corrispondenti celle del foglio

N_combo = Range("NmaxCombo").Value
N_carichi = Range("NmaxCar").Value


Adesso ci servono i contatori dei due cicli che chiamo:
Count_Comb per il contatore delle combinazioni
Count_Car per il contatore dei carichi

quindi:
Dim Count_Comb as integer, Count_Car as integer

a questo punto siamo pronti per dare inizio ai cicli. Scrivo immediatamente la struttura:


For Count_Comb = 1 To N_comb

    For Count_Car = 1 To N_carichi
   
   
    Next

Next

Nel ciclo interno faremo eseguire le operazioni necessarie (somme e moltiplicazioni) per ricavare le componenti della risultante relativa alla combinazione del ciclo esterno corrente.
Ricordando che le operazioni da eseguire sono:
Fx = Fxo + somma.i[Fxi]
Fy = Fyo + somma.i[Fyi]
Fz = Fzo + somma.i[Fzi]
Mx = Mxo +somma.i[ Mxi +Fzi*(yi-yg) - Fyi*Hp]
My = Myo +somma.i[ Myi - Fzi*(xi-xg) + Fxi*Hp]
Mz = Mzo +somma.i[ Mzi - Fxi*(yi-yg) + Fyi*(xi-xg)]

e notando che ogni termine parte dal valore iniziale dato dalla corrispondente componente del carico dovuto al peso del plinto, conviene impostare il valore delle sei variabili da calcolare proprio al valore corrispondente del carico dovuto al peso del plinto, prima di entrare nel ciclo. Quindi avremo:

For Count_Comb = 1 To N_comb

    Fx = Range("TabCar0").Cells(Count_Comb, 1)
    Fy = Range("TabCar0").Cells(Count_Comb, 2)
    Fz = Range("TabCar0").Cells(Count_Comb, 3)
    Mx = Range("TabCar0").Cells(Count_Comb, 4)
    My = Range("TabCar0").Cells(Count_Comb, 5)
    Mz = Range("TabCar0").Cells(Count_Comb, 6)

    For Count_Car = 1 To N_carichi
   
   
    Next

Next

Qui è da annotare l'istruzione range().cells
Quando un range presente nel foglio è costituito da una matrice, per poter accedere alle proprieta della singola cella della matrice (ricordo che tra le proprietà di una cella c'è anche la proprietà .value che contiene il valore della cella), è necessario fare ricorso alla proprietà .cells del range. La proprieta .cells del range accetta le coordinate della cella all'interno della matrice sottoforma di (riga,colonna)
Se per esempio scriviamo
Range("matrice_nel_foglio").cells(2,5)
ci riferiamo alla cella ubicata nel secondo rigo della quinta colonna della tabella denominata "matrice_nel_foglio". Per ottenerne il valore basta richiamarsi la proprietà .value
Range("matrice_nel_foglio").cells(2,5).value

Spero sia chiaro

A questo punto non ci resta che completare le restenti tre formule che danno Mx, My ed Mz

Mx dovrebbe essere pari a:


Mx = Mx +  Range(tabella).Cells(Count_Comb, 4)+ Range(tabella).Cells(Count_Comb, 3)*(range("Tab_Coord_Car").cells(Count_Car,2)-y_g) - Range(tabella).Cells(Count_Comb, 2)*H_p

in cui
Range(tabella).Cells(Count_Comb, 4) è il valore della componente Mx del carico in esame
Range(tabella).Cells(Count_Comb, 3) è il valore della componente Fz del carico in esame
Range("Tab_Coord_Car").Cells(Count_Car, 2) è la ordinata del punto di applicazione del carico in esame
Range(tabella).Cells(Count_Comb, 2) è il valore della componente Fy del carico in esame

Se tutto è andato bene e non abbiamo commesso errori di sintassi, all'uscita del ciclo interno (quello dei carichi) dovremme avere le sei componenti della risultante relativa alla combinazione in corso e siamo pertanto in grado di riportarne i valori nella tabella del foglio che abbiamo dedicato a contenere le risultanti.
Questa tabella la avevamo chiamata semplicemente TabCar senza nessun numero.

Per scrivere il valore di una variabili VBA in una cella del foglio dovremo fare riscorso alla istruzione inversa alla lettura. in questo caso trattandosi ancora di una cella di una tabella, serve ricorrere nuovamente alla proprietà .cells(rigo,colonna).

Per scrivere la componente Fx della risultante scriveremo l'istruzione:

Range("TabCar").Cells(Count_Comb, 1).Value = Fx

mentre per scrivere le restanti componenti cambieremo l'indice da 1 a 2 a 3 a 4 a 5 a 6.
ottenendo una cosa del genere

Sub Calcola_Risultanti()

Dim Fx As Double
Dim Fy As Double
Dim Fz As Double
Dim Mx As Double
Dim My As Double
Dim Mz As Double

Dim X_g As Double
Dim Y_g As Double
Dim H_p As Double

X_g = Range("XG").Value
Y_g = Range("YG").Value
H_p = Range("HP").Value

Dim N_combo As Integer
Dim N_carichi As Integer

N_combo = Range("NmaxCombo").Value
N_carichi = Range("NmaxCar").Value

Dim tabella As String
Dim Count_Comb As Integer
Dim Count_Car As Integer

For Count_Comb = 1 To N_combo

    Fx = Range("TabCar0").Cells(Count_Comb, 1)
    Fy = Range("TabCar0").Cells(Count_Comb, 2)
    Fz = Range("TabCar0").Cells(Count_Comb, 3)
    Mx = Range("TabCar0").Cells(Count_Comb, 4)
    My = Range("TabCar0").Cells(Count_Comb, 5)
    Mz = Range("TabCar0").Cells(Count_Comb, 6)

    For Count_Car = 1 To N_carichi
        tabella = "TabCar" & Count_Car
   
        Fx = Fx + Range(tabella).Cells(Count_Comb, 1)
        Fy = Fy + Range(tabella).Cells(Count_Comb, 2)
        Fz = Fz + Range(tabella).Cells(Count_Comb, 3)
        Mx = Mx + _
              Range(tabella).Cells(Count_Comb, 4) + _
              Range(tabella).Cells(Count_Comb, 3) * (Range("Tab_Coord_Car").Cells(Count_Car, 2) - Y_g) - _
              Range(tabella).Cells(Count_Comb, 2) * H_p
        My = My + _
              Range(tabella).Cells(Count_Comb, 5) - _
              Range(tabella).Cells(Count_Comb, 3) * (Range("Tab_Coord_Car").Cells(Count_Car, 1) - X_g) + _
              Range(tabella).Cells(Count_Comb, 1) * H_p
        Mz = Mz + _
              Range(tabella).Cells(Count_Comb, 6) - _
              Range(tabella).Cells(Count_Comb, 1) * (Range("Tab_Coord_Car").Cells(Count_Car, 2) - Y_g) + _
              Range(tabella).Cells(Count_Comb, 2) * (Range("Tab_Coord_Car").Cells(Count_Car, 1) - X_g)
    Next
    Range("TabCar").Cells(Count_Comb, 1).Value = Fx
    Range("TabCar").Cells(Count_Comb, 2).Value = Fy
    Range("TabCar").Cells(Count_Comb, 3).Value = Fz
    Range("TabCar").Cells(Count_Comb, 4).Value = Mx
    Range("TabCar").Cells(Count_Comb, 5).Value = My
    Range("TabCar").Cells(Count_Comb, 6).Value = Mz
Next

End Sub

e col codice avremmo finito per adesso.

Ora dobbiamo creare un pulsante sul foglio alla cui pressione si attiva questa Sub.

Ho condotto le prime verifiche con calcoli a mano (sempre con l'ausilio del foglio). I risultati sembrano essere corretti. bene.

Se adesso provassimo a variare il numero delle combinazioni, per esempio dalle 8 che ho inserito come valore di "lavoro" a soli 3, accadrebbe che alla pressione del tasto "calcola risultanti" si aggiornerebbero solo le prime tre righe della tabella "TabCar" e resterebbero scritte le restanti 5 scritte nella prova precedente. Questo potrebbe causare qualche errore nella presentazione dei dati. Servirebbe quindi cancellare il contenuto della tabella TabCar prima di premere il tasto di esecuzione della Sub.
Capità però, col tempo, di non ricordare ciò. E' opportuno quindi prevedere la cancellazione dei dati contenuti in tabella attraverso codice e prima di riempirla. Ma quante righe dovremmo cancellare?
E' ragionevole supporre che difficilmente supereremo una cinquantina di combo, quindi fissiamo di cancellare 50 righe. Nel caso ci capitasse qualche cosa con piu di 50 combo saremo costretti a rivedere il codice, a meno che non registriamo da qualche parte, per esempio nel foglio di servizio, il numero delle righe da pulire. Seguiamo questa seconda via e dedichiamo una cella del foglio di servizio a contenere itale numero. Chiamiamo la cella col nome "N_righe_da_Pulire"



Uploaded with ImageShack.us

Adesso torniamo nel codice ed inseriamo:
- dimensionamento di una variabile N_R_C che ci indica il numero delle righe da cancellare: Dim N_R_C as integer
- lettura di N_R_C dal foglio mediante l'istruzione: N_R_C= range("N_righe_da_Pulire").value
- dimensionamento di un contatore generico: dim Count as integer.

A questo punto inseriamo il codice che cancella le righe da tabCar prima di entrare nei cicli che la riempiono.


Dim N_R_C As Integer
Dim Count As Integer
N_R_C = Range("N_righe_da_Pulire").Value

For Count = 1 To N_R_C
    Range("TabCar").Cells(Count, 1).Value = ""
    Range("TabCar").Cells(Count, 2).Value = ""
    Range("TabCar").Cells(Count, 3).Value = ""
    Range("TabCar").Cells(Count, 4).Value = ""
    Range("TabCar").Cells(Count, 5).Value = ""
    Range("TabCar").Cells(Count, 6).Value = ""

Next


Correggiamo ancora qualche imprecisione, per esempio l'unita di misura di Mp da [kN] a [kNm] e la dicitura "palipali" ed occupiamoci della distribuzione vera e propria.

Qui ricordo di aver lasciato ancora non conclusa la determinazione dell'azione orizzontale alla testa di ciascun palo a causa dell'azione orizzontale dovuta alla torsione mentre erano già definite le rimanenti:
per opportuna memoria, avevamo:

Npi = Ap* [ Fz/Atot  + Mx*(yi-yg)/Jxx - My*(xi-xg)/Jyy ]

Mpi = Tpi *lambda/2

restando ancora non determinato proprio Tpi.


Indicando con Txi e Tyi le sue componenti, avremo:

Tpi = radq( Txi² + Tyi²) ed a questo punto arrivati non ci interesserebbe il segno nè tampoco la direzione

Ciascuna delle due componenti risulta essere la somma:

Txi = Txi(Fx) + Txi(Mz)  [ azione orizzontale dovuta ad Fx e componente lungo x dell'azione dovuta alla torsione ]
Tyi = Tyi(Fy) + Tyi(Mz)  [ azione orizzontale dovuta ad Fy e componente lungo y dell'azione dovuta alla torsione ]

indicato con alfa l'angolo rispetto all'asse x della retta orientata su cui giace la reazione Tpi dovuta alla torsione e ricordando che Tpi = Mz *ri/somma[ri²], avremo:

Txi = Tx/Np + Mz*ri*cos(alfa)/somma[ri²]
Tyi = Ty/Np + Mz*ri*sen(alfa)/somma[ri²]

in cui sono:

ri = radq[ (xi-xg)² +(yi-yg)²]
alfa = arctg[(yi-yg)/(xi-xg)] + pigreco/2

Qui il problema è la funzione arctg che restituisce sempre un angolo compreso tra -pigreco/2 e +pigreco/2 e quindi ci serve esaminare il segno del rapporto [(yi-yg)/(xi-xg)]  per riportare l'angolo nel quadrante esatto.
Nel caso della funzione di foglio ARCTG(num) basta vedere solo il segno di (xi-xg) e se questo è negativo sommare al risultato fornito dalla funzione il valore pigreco.
Inoltre esiste anche la possibilita di incorrere nell'errore  #NUM quando l'ascissa di un palo coincide con l'ascissa del baricentro. In questo caso dovremmo far restituire pigreco/2 o -pigreco/2 a seconda del segno di (yi-yg).

Ovviamente tutto questo procedimento è gestibile anche ricorrendo alle sole funzioni di foglio, senza cioè fare ricorso a codice, ma la cosa sarebbe alquanto laboriosa. Vedrò nei prossimi giorni come affrontare e risolvere questo problema.

Scusami afazio se interrompo la tua continuità e costanza.

La tabella Tab_gammaF viene da te utilizzata solamente per 'amplificare' il peso del plinto.
Si presuppone quindi che le azioni esterne dei 5 possibili carichi che stai considerando siano già affette dei vari coefficienti parziali di combinazione.

Trovo 'strani' alcuni numeri che tu hai assegnato alla tabella suddetta (1.5 ad esempio). Trattasi di solamente di "numeri in libertà" immagino.
Bene sarebbe avere anche una descrizione della combo. Cioè se trattasi, almeno, di una SLU, SLE, ecc.

Si zax. Ho immaginato che le sollecitazioni (quelle che io chiamo carichi sull'estradosso del plinto) derivino da una analisi strutturale e che quindi arrivino comprensivi dei coefficienti parziali dei carichi, mentre il peso del plinto deve ancora essere moltiplicato per il proprio gamma.F.
I numeri che ho dato in quella tabella che vedi sono numeri a caso solo per poter visualizzare i risultati delle formule che vado via via inserendo
Per quanto riguarda la descrizione del tipo di combo, in effetti hai ragione. penso di inserire una ulteriore colonna prima del coefficiente gamma.F dove poter inserire questa descrizione.

Grazie